Archivo de la etiqueta: INDY

La clase TIdMessageBuilderHtml y el envío de correos HTML desde Delphi

Hay muchas formas de enviar correos con Delphi.

Mi preferida desde hace tiempo es hacerlo vía SMTP con la clase TIdSMTP, que es flexible y poderosa.

Hoy, a raíz de que mi estimado amigo, Edgar Ramírez, publicara su artículo Enviar correo con imágenes incrustadas con Delphi he recordado que hace tiempo me gustaría iniciar una serie de artículos sobre el uso de INDY y la comunicación TCP/IP con Delphi.

A manera de respuesta a la publicación citada, quiero mostrar cómo realizar el envío de un correo similar —con una imagen incrustada— haciendo uso de la clase auxiliar TIdMessageBuilderHtml, que en mi opinión no solo facilita las cosas sino que nos deja una solución mucho más elegante y fácil de entender en el código.

La parte relevante del envío de correo es:

procedure TfrmCorreo.EnviaCorreoImagen(const FileName: string);
var
  Builder: TIdMessageBuilderHtml;
  Msg: TIdMessage;
  SMTP: TIdSMTP;
begin
  Builder := TIdMessageBuilderHtml.Create;
  try
    Builder.Html.Add('<HTML><HEAD><TITLE>Una imagen para ti</TITLE></HEAD><BODY>');
    Builder.Html.Add('<p><strong>Una imagen para ti</strong></p>');
    Builder.Html.Add('<div>');
    Builder.Html.Add('  <img border="0" src="cid:laimagen" >');
    Builder.Html.Add('</div>');
    Builder.PlainText.Add('Este correo contiene una imágen para ti. '
      + 'Debes usar un visor HTML para verla');
    Builder.HtmlFiles.Add(FileName, 'laimagen');
    Msg := Builder.NewMessage();
    try
      Msg.Recipients.EMailAddresses := eRecipients.Text;
      Msg.From.Name := eFromName.Text;
      Msg.From.Address := eFromEmail.Text;
      Msg.Subject := 'Una imagen para ti';
      SMTP := TIdSMTP.Create;
      try
        SMTP.Host := eSMTPHost.Text;
        SMTP.Username := eSMTPUser.Text;
        SMTP.Password := eSMTPPass.Text;
        SMTP.Connect;
        try
          SMTP.Send(Msg);
        finally
          SMTP.Disconnect;
        end;
      finally
        SMTP.Free;
      end;
    finally
      Msg.Free;
    end;
  finally
    Builder.Free;
  end;
end;

Como puede observarse, la instancia de TIdMessageBuilderHtml se encarga de los detalles sobre adjuntar los archivos. De lo que debemos asegurarnos es de proveer un cid diferente para cada imagen incluida en el HTML de nuestro correo, y que estos identificadores se correspondan con los archivos incluidos posteriormente en la llamada al método HtmlFiles.Add, que recibe como parámetros el nombre del archivo y el cid correspondiente.

Aclaración: En mi opinión cualquier método con más de 25 líneas de código es demasiado grande y debe considerarse su refactorización. Es el caso del código publicado, sin embargo he preferido mantener un solo método para no enredar al lector con tener que seguir mentalmente las llamadas entre ellos. Como se ve, el método se encarga de todo el envío del correo, lo cuál conceptualmente también puede ser mucho para un solo método. En algo para producción, esto probablemente sería dividido en 3 distintos métodos: armar el correo HTML, configurar el mensaje y finalmente la conexión/envío/desconexión.

INDY: Finalmente se hizo el merge del branch Tiburon en el trunk

Indy Sockets, la popular biblioteca de clases para programación TCP/IP que viene con Delphi, finalmente ha completado el merge del branch Tiburon de regreso al trunk.

Si no estás familiarizado con la terminología del control de versiones, particularmente SubVersion, lo que esto significa es que el código fuente, que alguna vez se ramificó del desarrollo principal (branch), para soportar el cambio a Unicode en los tiempos de Delphi 2009 (llamado Tiburon), finalmente ha sido llevado de regreso (merge) a la raíz del desarrollo (trunk).

No es que hasta ahora se terminara de portar el código… en realidad es que luego de realizar las adaptaciones necesarias, quién sabe por qué, el equipo de INDY siguió desarrollando en el branch y el código nunca se integró de vuelta. Ahora lo hacen, en parte, porque estamos próximos a ver el inicio del desarrollo de INDY 11 (probablemente otro release que romperá la compatibilidad con el código existente).

En conclusión

  • Si obtenés el código de INDY directamente de SVN, deberás configurar el cliente para que obtenga el código de trunk y no de branches/tiburon, como lo haces ahora
  • Si obtenés el código de INDY descargando el ZIP del mirror, ahora debes descargar el archivo Indy10_xxxx.zip y no el Indy10Tiburon_xxx.zip
  • Si aún compilas con versiones viejas de SVN, mi consejo es que lo actualicés y te hagás a la idea que es buena idea mantenerlo actualizado 😉

Como es costumbre en INDY, la documentación oficial (incluyendo el sitio de descarga) aún no refleja esta información, y será actualizada pronto.

Vía anuncios de Remy Lebeau en foros Embarcadero y foros Atozed Software